ArcSinh
ArcSinh[z]
gives the inverse hyperbolic sine 
of the complex number 
.
Details
- Mathematical function, suitable for both symbolic and numerical manipulation.
- For certain special arguments, ArcSinh automatically evaluates to exact values.
- ArcSinh can be evaluated to arbitrary numerical precision.
- ArcSinh automatically threads over lists.
- ArcSinh[z] has branch cut discontinuities in the complex
plane running from 
to 
and 
to 
. - ArcSinh can be used with Interval and CenteredInterval objects. »
Background & Context
- ArcSinh is the inverse hyperbolic sine function. For a real number
, ArcSinh[x] represents the hyperbolic angle measure 
such that 
. - ArcSinh automatically threads over lists. For certain special arguments, ArcSinh automatically evaluates to exact values. When given exact numeric expressions as arguments, ArcSinh may be evaluated to arbitrary numeric precision. Operations useful for manipulation of symbolic expressions involving ArcSinh include FunctionExpand, TrigToExp, TrigExpand, Simplify, and FullSimplify.
- ArcSinh is defined for complex argument
by 
. ArcSinh[z] has branch cut discontinuities in the complex 
plane. - Related mathematical functions include Sinh, ArcCosh, and ArcSin.
Examples
open all close allBasic Examples (6)
ArcSinh[1.5]Plot over a subset of the reals:
Plot[ArcSinh[x], {x, -10, 10}]Plot over a subset of the complexes:
ComplexPlot3D[ArcSinh[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]Series[ArcSinh[x], {x, 0, 10}]Asymptotic expansion at Infinity:
Series[ArcSinh[x], {x, ∞, 3}]Asymptotic expansion at a singular point:
Series[ArcSinh[x], {x, I, 3}, Assumptions -> x > 1]Scope (45)
Numerical Evaluation (6)
ArcSinh[1.0]N[ArcSinh[1], 100]The precision of the output tracks the precision of the input:
ArcSinh[1.000000000000000000000000000000000000000000000000000000]Evaluate for complex arguments:
ArcSinh[1.5 + 0.7I]Evaluate ArcSinh efficiently at high precision:
ArcSinh[1`500]//TimingArcSinh[1`100000];//TimingCompute worst-case guaranteed intervals using Interval and CenteredInterval objects:
ArcSinh[Interval[{-5 / 2, Sinh[2]}]]ArcSinh[CenteredInterval[3, 1 / 100]]ArcSinh[CenteredInterval[2 + 3I, (1 + I) / 100]]Or compute average-case statistical intervals using Around:
ArcSinh[Around[.9, 0.1]]Compute the elementwise values of an array:
ArcSinh[{{I, I / Sqrt[2]}, {0, -I / Sqrt[2]}}]Or compute the matrix ArcSinh function using MatrixFunction:
MatrixFunction[ArcSinh[#]&, {{I, I / Sqrt[2]}, {0, -I / Sqrt[2]}}]Specific Values (4)
Values of ArcSinh at fixed points:
Table[ArcSinh[(n /2)I], {n, -2, 2}]ArcSinh[Infinity]ArcSinh[ComplexInfinity]Zero of ArcSinh:
ArcSinh[0]Find the value of 
satisfying equation 
:
f[x_] := ArcSinh[x] - Log[2];sol = Solve[f[x] == 0, x]xzero = x /. First[sol]Plot[f[x], {x, 0, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]Visualization (3)
Plot the ArcSinh function:
Plot[ArcSinh[x], {x, -50, 50}]
ComplexContourPlot[Re[ArcSinh[z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]
ComplexContourPlot[Im[ArcSinh[z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]
Table[PolarPlot[ArcSinh[k ϕ], {ϕ, -10π, 10π}, Frame -> True, Exclusions -> None, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-6, 6}, {-6, 6}}, FrameTicks -> {{{-6, -3, 0, 3, 6}, None}, {{-6, -3, 0, 3, 6}, None}}], {k, 1, 4}]Function Properties (12)
ArcSinh is defined for all real and complex values:
FunctionDomain[ArcSinh[x], x]FunctionDomain[ArcSinh[z], z, Complexes]ArcSinh achieves all real values:
FunctionRange[ArcSinh[x], x, y]Function range for arguments from the complex domain:
FunctionRange[ArcSinh[z], z, y, Complexes]ArcSinh is an odd function:
ArcSinh[-x]ArcSinh has the mirror property ![sinh^(-1)(TemplateBox[{z}, Conjugate])=TemplateBox[{{{sinh, ^, {(, {-, 1}, )}}, (, z, )}}, Conjugate]](https://reference.wolfram.com/Files/ArcSinh.en/19.png "sinh^(-1)(TemplateBox[{z}, Conjugate])=TemplateBox[{{{sinh, ^, {(, {-, 1}, )}}, (, z, )}}, Conjugate]"){kind=small}
:
FullSimplify[ArcSinh[Conjugate[z]] == Conjugate[ArcSinh[z]]]
is an analytic function of 
over the reals:
FunctionAnalytic[ArcSinh[x], x]It is neither analytic nor meromorphic over the complexes:
FunctionAnalytic[ArcSinh[x], x, Complexes]FunctionMeromorphic[ArcSinh[x], x]ArcSinh is non-decreasing:
FunctionMonotonicity[ArcSinh[x], x]ArcSinh is injective:
FunctionInjective[ArcSinh[x], x]Plot[{ArcSinh[x], 1}, {x, -4, 4}]ArcSinh is surjective:
FunctionSurjective[ArcSinh[x], x]Plot[{ArcSinh[x], 10}, {x, -50000, 50000}, PlotRange -> {-12, 12}]ArcSinh is neither non-negative nor non-positive:
FunctionSign[ArcSinh[x], x]ArcSinh has no singularities or discontinuities:
FunctionSingularities[ArcSinh[x], x]FunctionDiscontinuities[ArcSinh[x], x]ArcSinh is neither convex nor concave:
FunctionConvexity[ArcSinh[x], x]TraditionalForm formatting:
ArcSinh[x]//TraditionalFormDifferentiation (3)
D[ArcSinh[x], x]Table[D[ArcSinh[x], {x, n}], {n, 1, 4}]Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]
derivative:D[ArcSinh[x], {x, n}]Integration (3)
Indefinite integral of ArcSinh:
Integrate[ArcSinh[x], x]Definite integral of ArcSinh over an interval centered at the origin is 0:
Integrate[ArcSinh[x], {x, -2, 2}]Integrate[ArcSinh[x] x, x]Integrate[ArcSinh[x] ^ a, x]Series Expansions (4)
Find the Taylor expansion using Series:
Series[ArcSinh[x], {x, 0, 7}]Plot the first three approximations for ArcSinh around 
:
terms = Normal@Table[Series[ArcSinh[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{ArcSinh[x], terms}, {x, -1.5, 1.5}, PlotRange -> {{-1.5, 1.5}, All}]General term in the series expansion of ArcSinh:
SeriesCoefficient[ArcSinh[x], {x, 0, n}]Find series expansions at branch points and branch cuts:
Series[ArcSinh[x], {x, I, 4}]Series[ArcSinh[x], {x, -2I, 4}]ArcSinh can be applied to a power series:
ArcSinh[Cos[x] + O[x] ^ 10]Integral Transforms (2)
Compute the Fourier transform using FourierTransform:
FourierTransform[ArcSinh[t], t, ω]HankelTransform[ArcSinh[r], r, s]Function Identities and Simplifications (3)
Simplify expressions involving ArcSinh:
FullSimplify[Sinh[ArcSinh[x] + ArcSinh[y]]^4 - 2(2y^2 x^2 + x^2 + y^2)Sinh[ArcSinh[x] + ArcSinh[y]]^2 + (x^2 - y^2)^2]Use TrigToExp to express ArcSinh using logarithm:
TrigToExp@ArcSinh[z]ExpToTrig[%]Expand assuming real variables 
and 
:
ComplexExpand[ArcSinh[x + I y]]Function Representations (5)
Represent using ArcCsch:
ArcCsch[1 / x]//FullSimplifyRepresentation through inverse Jacobi functions:
InverseJacobiCS[(1/z), 1]//FullSimplifyInverseJacobiSC[z, 1]Represent using Hypergeometric2F1:
x Hypergeometric2F1[(1/2), (1/2), (3/2), -x^2]ArcSinh can be represented in terms of MeijerG:
MeijerGReduce[ArcSinh[x], x]Activate[%]ArcSinh can be represented as a DifferentialRoot:
DifferentialRootReduce[ArcSinh[x], x]Applications (3)
Compute the length of hyperbola 
from the base to given 
:
Integrate[Sqrt[D[Sqrt[1 + t ^ 2], t] ^ 2 + 1], {t, 0, x}, Assumptions -> x > 0]N[% /. x -> 3, 20]Solve a differential equation:
DSolve[{(1 + x^2) y''[x] + x y'[x] == 1, y[0] == 0, y'[0] == 1}, y[x], x]Solution of the sinh‐Gordon equation 
:
u[x_, t_] := 2ArcSinh[JacobiCS[x - t, m]]FullSimplify[D[u[x, t], x, t] + Sinh[u[x, t]], JacobiNS[t - x, m] ^ 2 - JacobiCS[t - x, m] ^ 2 == 1]Plot3D[Evaluate[u[x, t] /. m -> 4 / 3], {x, -3, 2}, {t, 0, 5 / 2}]Properties & Relations (4)
Compose with the inverse function:
{ArcSinh[Sinh[z]], Sinh[ArcSinh[z]]}Use PowerExpand to disregard multivaluedness of the ArcSinh:
PowerExpand[%]Alternatively, evaluate under additional assumptions:
Refine[ArcSinh[Sinh[z]], z∈Reals]Use TrigToExp to express ArcSinh using logarithm:
ArcSinh[z]//TrigToExpExpToTrig[%]Use Reduce to solve an equation in terms of ArcSinh:
Reduce[Sinh[x] == y, x]ArcSinh is a special case of some special functions:
x Hypergeometric2F1[1 / 2, 1 / 2, 3 / 2, -x ^ 2]Possible Issues (2)
Related Links
MathWorld
The Wolfram Functions SiteText
Wolfram Research (1988), ArcSinh, Wolfram Language function, https://reference.wolfram.com/language/ref/ArcSinh.html (updated 2021).
CMS
Wolfram Language. 1988. "ArcSinh." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/ArcSinh.html.
APA
Wolfram Language. (1988). ArcSinh. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArcSinh.html