# compile this with

# $ peg jsonpath.peg (creates jsonpath.peg.go)

# using peg from https://github.com/pointlander/peg

package data

import "strings"

type jsonPeg Peg {

components []extractor

lastKey string

}

jsonPath <- (jsonPathHead / jsonArraySlices) jsonPathNonHead* !.

jsonPathHead <- (jsonMapAccessString / jsonMapAccessBracket) {

p.addMapAccess(p.lastKey)

}

jsonPathNonHead <- jsonMapMultipleLevel / jsonMapSingleLevel /

jsonArrayFullSlice / jsonArrayPartialSlice / jsonArraySlice / jsonArrayAccess

jsonMapSingleLevel <- (('.' jsonMapAccessString) / jsonMapAccessBracket) {

p.addMapAccess(p.lastKey)

}

# for single level it is `foo.bar` or `foo["bar"]`, but

# for recursion it is `foo..bar` or `foo..["bar"]`, that is

# a bit inconsistent

jsonMapMultipleLevel <- '..' (jsonMapAccessString / jsonMapAccessBracket) {

p.addRecursiveAccess(p.lastKey)

}

jsonMapAccessString <- < [[a-z]] ([[a-z]] / [0-9] / '_')* > {

substr := string([]rune(buffer)[begin:end])

p.lastKey = substr

}

jsonMapAccessBracket <- '[' (singleQuotedString / doubleQuotedString) ']'

# single quotes within a singleQuotedString must be doubled

singleQuotedString <- ['] < ("''" / !"'" .)* > ['] {

substr := string([]rune(buffer)[begin:end])

p.lastKey = strings.Replace(substr, "''", "'", -1)

}

# double quotes within a doubleQuotedString must be doubled

doubleQuotedString <- ["] < ('""' / !'"' .)* > ["] {

substr := string([]rune(buffer)[begin:end])

p.lastKey = strings.Replace(substr, "\"\"", "\"", -1)

}

jsonArraySlices <- jsonArrayAccess / jsonArraySlice / jsonArrayPartialSlice /

jsonArrayFullSlice

jsonArrayAccess <- '[' < '-'? [0-9]+ > ']' {

substr := string([]rune(buffer)[begin:end])

p.addArrayAccess(substr)

}

jsonArraySlice <- '[' < '-'? [0-9]+ ':' '-'? [0-9]+ (':' '-'? [0-9]+)? > ']' {

substr := string([]rune(buffer)[begin:end])

p.addArraySlice(substr)

}

jsonArrayPartialSlice <- '[' < (':' '-'? [0-9]+) / ('-'? [0-9]+ ':') > ']' {

substr := string([]rune(buffer)[begin:end])

p.addArraySlice(substr)

}

jsonArrayFullSlice <- '[:]' {

p.addArraySlice("0:")

}