@echo off

if "%~1"=="__run__" goto run

copy /y "%~f0" "%TEMP%\fsa-update.bat" >nul

call "%TEMP%\fsa-update.bat" __run__ "%~dp0"

exit /b %errorlevel%

:run

cd /d "%~2.."

for %%r in (fullstack-agent ai-memory-vault backtalk barehands ai-visualizer) do (

if exist "%%r\.git\" call :one "%%r"

)

echo update complete.

if not exist "%USERPROFILE%\Desktop\Update *" echo Tip: want a desktop Update icon that does this on a double-click? Open your agent and ask for one.

exit /b 0

:one

echo == %~1

git -C "%~1" fetch -q origin 2>nul

git -C "%~1" log --oneline "..@{u}" 2>nul

set CFG=

if "%~1"=="backtalk" set CFG=backtalk.json

if "%~1"=="barehands" set CFG=barehands.json

if "%~1"=="ai-visualizer" set CFG=ai-visualizer.json

set MIGRATE=0

if not defined CFG goto pull

if not exist "%~1\%CFG%" goto pull

git -C "%~1" ls-files --error-unmatch "%CFG%" >nul 2>nul

if errorlevel 1 goto pull

copy /y "%~1\%CFG%" "%~1\%CFG%.mine" >nul

git -C "%~1" checkout -- "%CFG%"

set MIGRATE=1

:pull

git -C "%~1" pull --ff-only

if "%MIGRATE%"=="1" if exist "%~1\%CFG%.mine" move /y "%~1\%CFG%.mine" "%~1\%CFG%" >nul

exit /b 0