use 5.14.0;

use strict;

use warnings;

use lib qw(. lib local/lib/perl5);

use Bugzilla;

use Bugzilla::Attachment;

use Bugzilla::BugMail;

use Bugzilla::Constants;

use Bugzilla::Util;

use Bugzilla::Error;

use Bugzilla::Bug;

use Bugzilla::User;

use Bugzilla::Hook;

use Bugzilla::Token;

use Bugzilla::Flag;

use List::MoreUtils qw(uniq);

my $user = Bugzilla->login(LOGIN_REQUIRED);

my $cgi = Bugzilla->cgi;

my $dbh = Bugzilla->dbh;

my $template = Bugzilla->template;

my $vars = {};

unless ($cgi->param()) {

print $cgi->redirect(correct_urlbase() . 'enter_bug.cgi');

exit;

}

my $token = trim(scalar $cgi->param('token'));

check_token_data($token, 'create_bug', 'index.cgi');

Bugzilla::User::match_field ({

'cc' => { 'type' => 'multi' },

'assigned_to' => { 'type' => 'single' },

'qa_contact' => { 'type' => 'single' },

});

if (defined $cgi->param('maketemplate')) {

$vars->{'url'} = $cgi->canonicalise_query('token');

print $cgi->header();

$template->process("bug/create/make-template.html.tmpl", $vars)

|| ThrowTemplateError($template->error());

exit;

}

my $comment;

my $format = $template->get_format("bug/create/comment",

scalar($cgi->param('format')), "txt");

$template->process($format->{'template'}, $vars, \$comment)

|| ThrowTemplateError($template->error());

my @custom_bug_fields = grep {$_->type != FIELD_TYPE_MULTI_SELECT && $_->enter_bug}

Bugzilla->active_custom_fields;

my @bug_fields = grep { defined $cgi->param($_->name) } @custom_bug_fields;

@bug_fields = map { $_->name } @bug_fields;

push(@bug_fields, qw(

));

my %bug_params;

foreach my $field (@bug_fields) {

$bug_params{$field} = $cgi->param($field);

}

foreach my $field (qw(cc groups)) {

next if !$cgi->should_set($field);

$bug_params{$field} = [$cgi->multi_param($field)];

}

$bug_params{'comment'} = $comment;

$bug_params{'is_markdown'} = $cgi->param('use_markdown');

my @multi_selects = grep {$_->type == FIELD_TYPE_MULTI_SELECT && $_->enter_bug}

Bugzilla->active_custom_fields;

foreach my $field (@multi_selects) {

next if !$cgi->should_set($field->name);

$bug_params{$field->name} = [$cgi->multi_param($field->name)];

}

my $product = Bugzilla::Product->check($bug_params{'product'});

my $component_id = Bugzilla::Component->check({

product => $product,

name => $bug_params{'component'}})->id;

my (undef, $flag_data) = Bugzilla::Flag->extract_flags_from_cgi($vars, SKIP_REQUESTEE_ON_ERROR,{

product_id => $product->id,

component_id => $component_id });

$bug_params{flags} = $flag_data;

my $bug = Bugzilla::Bug->create(\%bug_params);

my $id = $bug->bug_id;

delete_token($token);

my $timestamp = $dbh->selectrow_array(

'SELECT creation_ts FROM bugs WHERE bug_id = ?', undef, $id);

if (defined $cgi->param('version')) {

$cgi->send_cookie(-name => "VERSION-" . $bug->product,

-value => $bug->version,

-expires => "Fri, 01-Jan-2038 00:00:00 GMT");

}

my $data_fh = $cgi->upload('data');

my $attach_text = $cgi->param('attach_text');

if ($data_fh || $attach_text) {

$cgi->param('isprivate', scalar $cgi->param('comment_is_private'));

# Must be called before create() as it may alter $cgi->param('ispatch').

my $content_type = Bugzilla::Attachment::get_content_type();

my $attachment;

# If the attachment cannot be successfully added to the bug,

# we notify the user, but we don't interrupt the bug creation process.

my $error_mode_cache = Bugzilla->error_mode;

Bugzilla->error_mode(ERROR_MODE_DIE);

eval {

$attachment = Bugzilla::Attachment->create(

{bug => $bug,

creation_ts => $timestamp,

data => $attach_text || $data_fh,

description => scalar $cgi->param('description'),

filename => $attach_text ? "file_$id.txt" : $data_fh,

ispatch => scalar $cgi->param('ispatch'),

isprivate => scalar $cgi->param('isprivate'),

mimetype => $content_type,

});

};

Bugzilla->error_mode($error_mode_cache);

if ($attachment) {

# Set attachment flags.

my ($flags, $new_flags) = Bugzilla::Flag->extract_flags_from_cgi(

$vars, SKIP_REQUESTEE_ON_ERROR,

{ bug => $bug, attachment => $attachment });

$attachment->set_flags($flags, $new_flags);

$attachment->update($timestamp);

my $comment = $bug->comments->[0];

$comment->set_all({ type => CMT_ATTACHMENT_CREATED,

extra_data => $attachment->id });

$comment->update();

}

else {

$vars->{'message'} = 'attachment_creation_failed';

}

}

$vars->{'id'} = $id;

$vars->{'bug'} = $bug;

Bugzilla::Hook::process('post_bug_after_creation', { vars => $vars });

my $recipients = { changer => $user };

my $bug_sent = Bugzilla::BugMail::Send($id, $recipients);

$bug_sent->{type} = 'created';

$bug_sent->{id} = $id;

my @all_mail_results = ($bug_sent);

foreach my $dep (@{$bug->dependson || []}, @{$bug->blocked || []}) {

my $dep_sent = Bugzilla::BugMail::Send($dep, $recipients);

$dep_sent->{type} = 'dep';

$dep_sent->{id} = $dep;

push(@all_mail_results, $dep_sent);

}

foreach my $ref_bug_id (uniq @{ $bug->{see_also_changes} || [] }) {

my $ref_sent = Bugzilla::BugMail::Send($ref_bug_id, $recipients);

$ref_sent->{id} = $ref_bug_id;

push(@all_mail_results, $ref_sent);

}

$vars->{sentmail} = \@all_mail_results;

$format = $template->get_format("bug/create/created",

scalar($cgi->param('created-format')),

"html");

print $cgi->header();

$template->process($format->{'template'}, $vars)

|| ThrowTemplateError($template->error());

1;