Refactor the phlow details view to make it easier to create the remove view [feenkcom/gtoolkit#5059]

chisandrei · chisandrei · commit 0de0095f5f90 · 2026-06-24T14:34:19.000+02:00
diff --git a/src/GToolkit-Phlow/GtPhlowDetailsElement.class.st b/src/GToolkit-Phlow/GtPhlowDetailsElement.class.st
@@ -0,0 +1,132 @@
+Class {
+	#name : #GtPhlowDetailsElement,
+	#superclass : #BrFrame,
+	#instVars : [
+		'gridElement',
+		'detailsView'
+	],
+	#category : #'GToolkit-Phlow-! Views'
+}
+
+{ #category : #initialization }
+GtPhlowDetailsElement >> configureRowName: rowNameLabel value: rowValueLabel fromRow: aRow [
+	| clickHandler eventSharer|
+	
+	clickHandler := BlEventHandler on: BlClickEvent
+				do: 
+					[:anEvent |
+
+					rowValueLabel viewModel ifNotNil: [
+						anEvent consumed: true.
+						rowValueLabel phlow 
+							spawnObject: (
+								detailsView localSend 
+									ifNil: [rowValueLabel viewModel model] 
+									ifNotNil: [ :aBlock |
+										aBlock cull: aRow cull: rowValueLabel viewModel model] ) ]].
+	
+	eventSharer := BlSharedEventDistributor shareEvents: {
+		BlMouseEnterEvent.
+		BlMouseLeaveEvent.
+		BlMouseDownEvent.
+		BlMouseUpEvent.
+		BlDragLeaveEvent.
+		BlDragEndEvent }.
+	
+	rowNameLabel addEventHandler: eventSharer.
+	rowValueLabel addEventHandler: eventSharer.
+	
+	rowNameLabel addEventHandler: clickHandler.
+	rowValueLabel addEventHandler: clickHandler
+]
+
+{ #category : #'building widgets' }
+GtPhlowDetailsElement >> createHeaderCell: aString [
+	^ (BrLabel new)
+				aptitude: (BrGlamorousLabelAptitude new foreground: Color gray);
+				hFitContent;
+				padding: (BlInsets top: 3 left: 6 bottom: 3 right: 6);
+				text: aString
+]
+
+{ #category : #'building widgets' }
+GtPhlowDetailsElement >> createRowName: eachRow [
+	^(BrLabel new)
+		aptitude: (BrGlamorousLabelAptitude + BrGlamorousListItemAptitude);
+		hFitContent;
+		padding: (BlInsets top: 3 left: 6 bottom: 3 right: 6);
+		constraintsDo: [ :c | c grid horizontal specAlignment: BlGridAlignment fill ];
+		text: eachRow name
+]
+
+{ #category : #'building widgets' }
+GtPhlowDetailsElement >> createRowValue: eachRow [
+	| value text |
+	[
+		value := eachRow valueComputation value.
+		text := eachRow textComputation value: value.
+	] 
+		on: Exception 
+		do: [ :anException |
+			| anElement | 
+			anElement := anException asDebuggableElement. 
+			anElement id: GtPhlowExceptionId.
+			anElement phlow beViewContent; entity: detailsView.
+			^ anElement ].
+	 
+	^(BrLabel new)
+		in: [:aLabel | aLabel viewModel model: value];
+		aptitude: BrGlamorousLabelAptitude + BrGlamorousListItemAptitude;
+		hMatchParent;
+		padding: (BlInsets
+					top: 3
+					left: 6
+					bottom: 3
+					right: 6);
+		text: text
+]
+
+{ #category : #initialization }
+GtPhlowDetailsElement >> detailsView: aDetailsView [
+	detailsView := aDetailsView.
+	self updateContent.
+]
+
+{ #category : #initialization }
+GtPhlowDetailsElement >> initialize [
+	super initialize.
+	
+	self hMatchParent.
+	self vFitContent.
+	
+	gridElement := BrHorizontalGrid new.
+	gridElement columnCount: 2.
+	gridElement cellSpacing: 0.
+	gridElement hMatchParent.
+	gridElement vFitContent.
+			
+	self addChild: gridElement.
+]
+
+{ #category : #initialization }
+GtPhlowDetailsElement >> updateContent [
+	| headerElements cellElements |
+	
+	gridElement removeChildren.
+	
+	headerElements := {
+			self createHeaderCell: 'Name'.
+			self createHeaderCell: 'Value' }.
+	cellElements := detailsView  phlowDetailRows 
+			flatCollect: [:eachRow |
+					 | rowName rowValue |
+					 rowName := self createRowName: eachRow.
+					 rowValue := self createRowValue: eachRow.
+					 
+					 self configureRowName: rowName value: rowValue fromRow: eachRow.
+					
+					{ rowName . rowValue}].
+					
+	gridElement addChildren: headerElements.
+	gridElement addChildren: cellElements.
+]
diff --git a/src/GToolkit-Phlow/GtPhlowDetailsView.class.st b/src/GToolkit-Phlow/GtPhlowDetailsView.class.st
@@ -2,112 +2,22 @@ Class {
 	#name : #GtPhlowDetailsView,
 	#superclass : #GtPhlowViewDecorator,
 	#instVars : [
-		'rows'
+		'rows',
+		'localSend'
 	],
 	#category : #'GToolkit-Phlow-! Views'
 }
 
 { #category : #'api - converting' }
 GtPhlowDetailsView >> asElementDo: aBlockClosure [
-	| grid cells header |
-	grid := BrHorizontalGrid new.
-	grid columnCount: 2.
-	grid cellSpacing: 0.
-	grid hMatchParent.
-	grid vFitContent.
-	header :=
-			{self createHeaderCell: 'Name'.
-			self createHeaderCell: 'Value'}.
-	cells := rows flatCollect: 
-					[:eachRow |
-					
-					 | rowName rowValue |
-					 rowName := self createRowName: eachRow.
-					 rowValue := self createRowValue: eachRow.
-					 
-					 self configureRowName: rowName value: rowValue.
-					
-					{ rowName . rowValue}].
-	grid addChildren: header.
-	grid addChildren: cells.
-	grid := grid asScrollableElement.
-	self beViewElement: grid.
-	^aBlockClosure value: grid
-]
-
-{ #category : #'api - converting' }
-GtPhlowDetailsView >> configureRowName: rowNameLabel value: rowValueLabel [
-	| clickHandler eventSharer|
-	
-	clickHandler := BlEventHandler on: BlClickEvent
-				do: 
-					[:anEvent |
-
-					rowValueLabel viewModel ifNotNil: [
-						anEvent consumed: true.
-						self inform: 'Spawn!'.
-						rowValueLabel phlow 
-							spawnObject: rowValueLabel viewModel model ]].
+	| detailsElement viewElement |
+	detailsElement := GtPhlowDetailsElement new
+		detailsView: self.
+	viewElement := detailsElement asScrollableElement.
 	
-	eventSharer := BlSharedEventDistributor shareEvents: {
-		BlMouseEnterEvent.
-		BlMouseLeaveEvent.
-		BlMouseDownEvent.
-		BlMouseUpEvent.
-		BlDragLeaveEvent.
-		BlDragEndEvent }.
+	self beViewElement: viewElement.
 	
-	rowNameLabel addEventHandler: eventSharer.
-	rowValueLabel addEventHandler: eventSharer.
-	
-	rowNameLabel addEventHandler: clickHandler.
-	rowValueLabel addEventHandler: clickHandler
-]
-
-{ #category : #'api - converting' }
-GtPhlowDetailsView >> createHeaderCell: aString [
-	^ (BrLabel new)
-				aptitude: (BrGlamorousLabelAptitude new foreground: Color gray);
-				hFitContent;
-				padding: (BlInsets top: 3 left: 6 bottom: 3 right: 6);
-				text: aString
-]
-
-{ #category : #'api - converting' }
-GtPhlowDetailsView >> createRowName: eachRow [
-	^(BrLabel new)
-		aptitude: (BrGlamorousLabelAptitude + BrGlamorousListItemAptitude);
-		hFitContent;
-		padding: (BlInsets top: 3 left: 6 bottom: 3 right: 6);
-		constraintsDo: [ :c | c grid horizontal specAlignment: BlGridAlignment fill ];
-		text: eachRow name
-]
-
-{ #category : #'api - converting' }
-GtPhlowDetailsView >> createRowValue: eachRow [
-	| value text |
-	[
-		value := eachRow valueComputation value.
-		text := eachRow textComputation value: value.
-	] 
-		on: Exception 
-		do: [ :anException |
-			| anElement | 
-			anElement := anException asDebuggableElement. 
-			anElement id: GtPhlowExceptionId.
-			anElement phlow beViewContent; entity: self.
-			^ anElement ].
-	 
-	^(BrLabel new)
-		in: [:aLabel | aLabel viewModel model: value];
-		aptitude: BrGlamorousLabelAptitude + BrGlamorousListItemAptitude;
-		hMatchParent;
-		padding: (BlInsets
-					top: 3
-					left: 6
-					bottom: 3
-					right: 6);
-		text: text
+	^aBlockClosure value: viewElement
 ]
 
 { #category : #views }
@@ -130,12 +40,23 @@ GtPhlowDetailsView >> initialize [
 	rows := OrderedCollection new
 ]
 
+{ #category : #private }
+GtPhlowDetailsView >> localSend [
+	^ localSend
+]
+
+{ #category : #private }
+GtPhlowDetailsView >> localSend: aBlock [
+	"Do not use; only used by remote views as an hack"
+	localSend := aBlock
+]
+
 { #category : #'as yet unclassified' }
 GtPhlowDetailsView >> phlowDetailRows [
 	^ rows
 ]
 
-{ #category : #'api - scripting' }
+{ #category : #private }
 GtPhlowDetailsView >> row: aString value: aBlockClosure [
 	rows add: (GtPhlowDetailsRow new
 		name: aString;
