import groovy.text.SimpleTemplateEngine

import org.sonar.build.BlackBoxTest

import static org.gradle.api.JavaVersion.VERSION_21

plugins {

// Ordered alphabetically

id 'com.github.hierynomus.license' version '0.16.1'

id "com.github.hierynomus.license-report" version "0.16.1" apply false

id 'com.gradleup.shadow' version '9.2.2' apply false

id 'com.google.protobuf' version '0.8.19' apply false

id 'com.jfrog.artifactory' version '6.0.4'

id "de.undercouch.download" version "5.7.0" apply false

id 'io.spring.dependency-management' version '1.1.7'

id "org.cyclonedx.bom" version "3.2.2" apply false

id 'org.sonarqube' version '7.2.3.7755'

}

if (!JavaVersion.current().isCompatibleWith(VERSION_21)) {

throw new GradleException("JDK 21+ is required to perform this build. It's currently " + System.getProperty("java.home") + ".")

}

def bomTasks = "cyclonedxBom"

def ghBranch = System.getenv()["GITHUB_REF_NAME"]

def isMainBranch = ghBranch in ['master'] || ghBranch ==~ 'branch-[\\d.]+'

boolean enableBom = System.getenv('CI') == "true" && (isMainBranch) ||

System.getProperty("bom") != null ||

gradle.startParameter.taskNames.findAll({ it.matches(".*:($bomTasks)") })

allprojects {

apply plugin: 'com.jfrog.artifactory'

apply plugin: 'maven-publish'

// Global exclusion of eddsa dependency

configurations.all {

exclude group: 'net.i2p.crypto', module: 'eddsa'

}

ext.versionInSources = version

ext.buildNumber = System.getProperty("buildNumber")

// when no buildNumber is provided, then project version must end with '-SNAPSHOT'

if (ext.buildNumber == null) {

version = "${version}-SNAPSHOT".toString()

ext.versionWithoutBuildNumber = version

} else {

ext.versionWithoutBuildNumber = version

version = (version.toString().count('.') == 1 ? "${version}.0.${ext.buildNumber}" : "${version}.${ext.buildNumber}").toString()

}

task cacheDependencies {

doLast {

configurations.each { conf ->

if (conf.isCanBeResolved()) {

if (conf.getName() != 'appZip')

conf.resolve()

}

}

}

}

ext {

release = project.hasProperty('release') && project.getProperty('release')

deployCommunity = project.hasProperty('deployCommunity') && (project.getProperty('deployCommunity') == 'true')

official = project.hasProperty('official') && project.getProperty('official')

}

ext.enableBom = enableBom

if (!enableBom) {

tasks.matching { it.name.matches(bomTasks) }.all({

logger.info("{} disabled", it.name);

it.enabled = false

})

}

repositories {

// For local development: resolve artifacts from local Maven repository

mavenLocal()

// The environment variables ARTIFACTORY_USERNAME and ARTIFACTORY_ACCESS_TOKEN are used on QA env (Jenkins)

// On local box, please add artifactoryUsername and artifactoryPassword to ~/.gradle/gradle.properties

def artifactoryUsername = System.env.'ARTIFACTORY_USERNAME' ?: (project.hasProperty('artifactoryUsername') ? project.getProperty('artifactoryUsername') : '')

def artifactoryPassword = System.env.'ARTIFACTORY_ACCESS_TOKEN' ?: (project.hasProperty('artifactoryPassword') ? project.getProperty('artifactoryPassword') : '')

def artifactoryUrl = System.getenv('ARTIFACTORY_URL') ?: (project.hasProperty('artifactoryUrl') ? project.getProperty('artifactoryUrl') : '')

if (artifactoryPassword) {

if (artifactoryUrl == '') {

throw new GradleException('Invalid artifactoryUrl')

}

maven {

authentication {

header(HttpHeaderAuthentication)

}

credentials(HttpHeaderCredentials) {

name = "Authorization"

value = "Bearer $artifactoryPassword"

}

url "${artifactoryUrl}/sonarsource"

}

maven {

authentication {

header(HttpHeaderAuthentication)

}

credentials(HttpHeaderCredentials) {

name = "Authorization"

value = "Bearer $artifactoryPassword"

}

url "${artifactoryUrl}/sonarsource-qa"

}

} else {

mavenCentral()

maven {

url 'https://jitpack.io'

}

maven {

url 'https://maven.codelibs.org/'

}

maven {

url 'https://build.shibboleth.net/nexus/content/repositories/releases/'

}

}

ivy {

if (artifactoryUsername && artifactoryPassword) {

url "${artifactoryUrl}/sonarsource-bucket"

authentication {

header(HttpHeaderAuthentication)

}

credentials(HttpHeaderCredentials) {

name = "Authorization"

value = "Bearer $artifactoryPassword"

}

patternLayout {

artifact '/[organisation]/[module]/[module]-[revision].[ext]'

}

} else {

// For public build

url "https://artifacts.elastic.co/downloads/"

patternLayout {

artifact '/[organisation]/[module]-[revision].[ext]'

}

}

metadataSources { artifact() }

}

}

task allDependencies {

dependsOn 'dependencies'

}

artifactory {

clientConfig.setIncludeEnvVars(true)

clientConfig.setEnvVarsExcludePatterns('*pass*,*psw*,*secret*,*MAVEN_CMD_LINE_ARGS*,sun.java.command,*token*,*login*,*key*,*signing*,*auth*,*pwd*')

clientConfig.publisher.setFilterExcludedArtifactsFromBuild(true)

contextUrl = System.getenv('ARTIFACTORY_URL')

//if property deployCommunity is true set the value to sonar-enterprise-sqcb

//otherwise set it to sqs

if (deployCommunity) {

clientConfig.info.setBuildName('sonar-enterprise-sqcb')

clientConfig.info.addEnvironmentProperty('ARTIFACTS_TO_PUBLISH',

"${project.group}:sonar-application:zip")

} else {

clientConfig.info.setBuildName('sonar-enterprise-sqs')

clientConfig.info.addEnvironmentProperty('ARTIFACTS_TO_PUBLISH',

"com.sonarsource.sonarqube:sonarqube-developer:zip," +

"com.sonarsource.sonarqube:sonarqube-datacenter:zip," +

"com.sonarsource.sonarqube:sonarqube-enterprise:zip")

}

publish {

repository {

repoKey = System.getenv('ARTIFACTORY_DEPLOY_REPO')

username = System.getenv('ARTIFACTORY_DEPLOY_USERNAME') ?: project.properties.artifactoryUsername

password = System.getenv('ARTIFACTORY_DEPLOY_PASSWORD') ?: project.properties.artifactoryPaswword

}

defaults {

properties = [

'build.name' : 'sonar-enterprise-sqcb',

'build.number' : System.getenv('BUILD_NUMBER'),

'pr.branch.target': System.getenv('GITHUB_BASE_REF'),

'pr.number' : System.getenv('PULL_REQUEST'),

'vcs.branch' : ghBranch,

'vcs.revision' : System.getenv('GITHUB_SHA'),

'version' : version

]

publications('mavenJava')

publishPom = true

publishIvy = false

}

}

clientConfig.info.setBuildNumber(System.getenv('BUILD_NUMBER'))

// The name of this variable is important because it's used by the delivery process when extracting version from Artifactory build info.

clientConfig.info.addEnvironmentProperty('PROJECT_VERSION', "${version}")

}

}

apply plugin: 'org.sonarqube'

sonar {

properties {

property 'sonar.projectName', projectTitle

property 'sonar.projectVersion', "${versionInSources}-SNAPSHOT"

property 'sonar.buildString', version

}

}

tasks.named('wrapper') {

distributionType = Wrapper.DistributionType.ALL

}

subprojects {

apply plugin: 'com.github.hierynomus.license'

apply plugin: 'io.spring.dependency-management'

apply plugin: 'jacoco'

apply plugin: 'java-library'

apply plugin: 'idea'

apply plugin: 'signing'

// do not deploy to Artifactory by default

artifactoryPublish.skip = true

compileJava.options.encoding = "UTF-8"

compileTestJava.options.encoding = "UTF-8"

def testFixtureSrc = 'src/testFixtures'

if (file(testFixtureSrc).exists()) {

apply plugin: 'java-test-fixtures'

}

java {

toolchain {

languageVersion = JavaLanguageVersion.of(21)

}

}

ext {

protobufVersion = '4.34.1'

springSecurityVersion = '7.0.4'

elasticSearchClientVersion = '7.17.29' // Old REST High Level Client (to be removed)

elasticSearchJavaClientVersion = '8.16.6' // New Java API Client

}

sonar {

properties {

property 'sonar.moduleKey', project.group + ':' + project.name

}

}

sourceSets {

test {

resources {

srcDirs += ['src/it/resources']

}

java {

srcDirs += ['src/it/java']

}

}

bbt {

resources {

srcDirs = ['src/bbt/resources']

}

java {

srcDirs = ['src/bbt/java']

}

}

}

configurations {

bbtCompile.extendsFrom testCompile

bbtRuntime.extendsFrom testRuntime

bbtImplementation.extendsFrom testImplementation

webapp {

transitive = false

}

// global exclusions and resolution strategies

all {

// do not conflict with com.sun.mail:javax.mail

exclude group: 'javax.mail', module: 'mail'

resolutionStrategy {

force 'net.java.dev.jna:jna:5.18.1'

// at.yawk.lz4:lz4-java is a drop-in replacement for org.lz4:lz4-java and declares the same capability.

// Prefer the newer fork over the version pulled in transitively by various libraries.

capabilitiesResolution.withCapability('org.lz4:lz4-java') {

selectHighestVersion()

}

}

}

// Exclude log4j-to-slf4j from test classpaths when log4j-core is present

// to avoid ClassCastException: SLF4JLoggerContext cannot be cast to LoggerContext

testRuntimeClasspath {

exclude group: 'org.apache.logging.log4j', module: 'log4j-to-slf4j'

}

}

// Central place for definition dependency versions and exclusions.

dependencyManagement {

dependencies {

// bundled plugin list -- keep it alphabetically ordered

dependency 'com.sonarsource.abap:sonar-abap-plugin:3.18.0.8030'

dependency 'com.sonarsource.armor:sonar-jasmin-plugin:1.16.0.10523'

dependency 'com.sonarsource.cobol:sonar-cobol-plugin:5.11.0.10062'

dependency 'com.sonarsource.cpp:sonar-cfamily-dependencies-plugin:6.80.0.98490'

dependency 'com.sonarsource.cpp:sonar-cfamily-plugin:6.80.0.98490'

dependency 'com.sonarsource.dart:sonar-dart-plugin:1.4.0.4183'

dependency 'com.sonarsource.dbd:sonar-dbd-plugin:2.7.0.20531'

dependency 'com.sonarsource.dbd:sonar-dbd-java-frontend-plugin:2.7.0.20531'

dependency 'com.sonarsource.dbd:sonar-dbd-python-frontend-plugin:2.7.0.20531'

dependency 'com.sonarsource.dotnet:sonar-csharp-enterprise-plugin:10.24.0.138807'

dependency 'com.sonarsource.dotnet:sonar-vbnet-enterprise-plugin:10.24.0.138807'

dependency 'com.sonarsource.dre:sonar-dre-plugin:2.1.0.11347'

dependency 'com.sonarsource.go:sonar-go-enterprise-plugin:1.36.0.5922'

dependency 'com.sonarsource.pli:sonar-pli-plugin:1.21.0.7212'

dependency 'com.sonarsource.plsql:sonar-plsql-plugin:3.18.1.230'

dependency 'com.sonarsource.plugins.vb:sonar-vb-plugin:2.17.0.7134'

dependency 'com.sonarsource.rpg:sonar-rpg-plugin:3.15.0.8032'

dependency 'com.sonarsource.security:sonar-security-csharp-frontend-plugin:11.28.0.45686'

dependency 'com.sonarsource.security:sonar-security-go-frontend-plugin:11.28.0.45686'

dependency 'com.sonarsource.security:sonar-security-java-frontend-plugin:11.28.0.45686'

dependency 'com.sonarsource.security:sonar-security-kotlin-frontend-plugin:11.28.0.45686'

dependency 'com.sonarsource.security:sonar-security-php-frontend-plugin:11.28.0.45686'

dependency 'com.sonarsource.security:sonar-security-plugin:11.28.0.45686'

dependency 'com.sonarsource.security:sonar-security-python-frontend-plugin:11.28.0.45686'

dependency 'com.sonarsource.security:sonar-security-vbnet-frontend-plugin:11.28.0.45686'

dependency 'com.sonarsource.slang:sonar-apex-plugin:1.24.0.2040'

dependency 'org.sonarsource.slang:sonar-ruby-plugin:1.22.0.1992'

dependency 'org.sonarsource.slang:sonar-scala-plugin:1.22.0.2217'

dependency 'com.sonarsource.swift:sonar-swift-plugin:5.2.0.12490'

dependency 'com.sonarsource.tsql:sonar-tsql-plugin:1.16.1.9133'

dependency 'org.sonarsource.dotnet:sonar-csharp-plugin:10.24.0.138807'

dependency 'org.sonarsource.dotnet:sonar-vbnet-plugin:10.24.0.138807'

dependency 'org.sonarsource.flex:sonar-flex-plugin:2.17.0.6043'

dependency 'org.sonarsource.go:sonar-go-plugin:1.36.0.5922'

dependency 'org.sonarsource.html:sonar-html-plugin:3.25.0.7473'

dependency 'org.sonarsource.jacoco:sonar-jacoco-plugin:1.5.1.5340'

dependency 'org.sonarsource.java:sonar-java-plugin:8.28.0.43176'

dependency 'org.sonarsource.java:sonar-java-symbolic-execution-plugin:8.16.4.1912'

dependency 'org.sonarsource.javascript:sonar-javascript-plugin:12.3.0.39932'

dependency 'org.sonarsource.php:sonar-php-plugin:3.56.0.15870'

dependency 'org.sonarsource.plugins.cayc:sonar-cayc-plugin:2.6.0.3665'

dependency 'org.sonarsource.python:sonar-python-plugin:5.21.0.32726'

dependency 'org.sonarsource.rust:sonar-rust-plugin:1.4.0.2802'

dependency 'com.sonarsource.python:sonar-python-enterprise-plugin:5.21.0.32726'

dependency 'org.sonarsource.kotlin:sonar-kotlin-plugin:3.5.0.9240'

dependency "org.sonarsource.api.plugin:sonar-plugin-api:$pluginApiVersion"

dependency "org.sonarsource.api.plugin:sonar-plugin-api-test-fixtures:$pluginApiVersion"

dependency "org.sonarsource.sonarqube:users-api:$usersApiVersion"

dependency "org.sonarsource.sonarqube:users-server-app:$usersApiVersion"

dependency 'org.sonarsource.xml:sonar-xml-plugin:2.16.0.7616'

dependency 'org.sonarsource.iac:sonar-iac-plugin:2.9.0.20183'

dependency 'com.sonarsource.iac:sonar-iac-enterprise-plugin:2.9.0.20183'

dependency 'org.sonarsource.text:sonar-text-plugin:2.42.0.10784'

dependency 'com.sonarsource.text:sonar-text-developer-plugin:2.42.0.10784'

dependency 'com.sonarsource.text:sonar-text-enterprise-plugin:2.42.0.10784'

dependency 'com.sonarsource.jcl:sonar-jcl-plugin:1.5.0.2979'

dependency 'com.sonarsource.architecture:sonar-architecture-plugin:2.26.0.9391'

dependency 'com.sonarsource.architecture:sonar-architecture-java-frontend-plugin:2.26.0.9391'

dependency 'com.sonarsource.architecture:sonar-architecture-javascript-frontend-plugin:2.26.0.9391'

// Webapp

dependency "org.sonarsource.sonarqube:webapp-assets:$webappVersion"

// Shared libraries from sonarqube-unification

dependencySet(group: 'org.sonarsource.sonarqube', version: '1.7.0.2189') {

entry 'sonar-db-commons'

entry 'sonar-db-commons-testfixtures'

entry 'sonar-spring'

}

dependency "org.sonarsource.sonarqube:organizations-api:$organizationsApiVersion"

dependency "org.sonarsource.sonarqube:organizations-server-app:$organizationsApiVersion"

// Keep in sync with sonar-sca's dependency management

dependency "org.sonarsource.sonarqube:sonar-feature-flags-api:$featureFlagsApiVersion"

dependency "org.sonarsource.sonarqube:sonar-events-server:$eventsApiVersion"

// please keep this list alphabetically ordered

dependencySet(group: 'ch.qos.logback', version: '1.5.32') {

entry 'logback-classic'

entry 'logback-core'

}

// https://mvnrepository.com/artifact/ch.qos.logback.access/common

dependency('ch.qos.logback.access:common:2.0.3')

dependency('ch.qos.logback.access:logback-access-tomcat:2.0.12')

dependency 'commons-codec:commons-codec:1.21.0'

dependency 'commons-dbutils:commons-dbutils:1.8.1'

dependency 'commons-io:commons-io:2.21.0'

imports { mavenBom 'com.fasterxml.jackson:jackson-bom:2.21.2' }

dependencySet(group: 'com.github.scribejava', version: '8.3.3') {

entry 'scribejava-apis'

entry 'scribejava-core'

}

dependency('com.github.erosb:json-sKema:0.29.0') {

// this version of json-sKema does not make use of commons-collections, so we can exclude it safely

exclude 'commons-collections:commons-collections'

}

// This project is no longer maintained and was forked

// by https://github.com/java-diff-utils/java-diff-utils

// (io.github.java-diff-utils:java-diff-utils).

dependency 'com.googlecode.java-diff-utils:diffutils:1.3.0'

dependency('com.googlecode.json-simple:json-simple:1.1.1') {

exclude 'junit:junit'

}

dependency 'io.github.hakky54:ayza:10.0.4'

dependency 'io.prometheus:simpleclient:0.16.0'

dependency 'io.prometheus:simpleclient_common:0.16.0'

dependency 'io.prometheus:simpleclient_servlet:0.16.0'

dependency 'io.swagger.parser.v3:swagger-parser:2.1.39'

dependency 'com.github.spotbugs:spotbugs-annotations:4.9.8'

dependency 'com.google.code.gson:gson:2.13.2'

dependency('com.google.guava:guava:33.5.0-jre') {

exclude 'com.google.errorprone:error_prone_annotations'

exclude 'com.google.guava:listenablefuture'

exclude 'com.google.j2objc:j2objc-annotations'

exclude 'org.checkerframework:checker-qual'

exclude 'org.codehaus.mojo:animal-sniffer-annotations'

}

dependency "com.google.protobuf:protobuf-java:${protobufVersion}"

dependency 'com.h2database:h2:2.3.232'

dependencySet(group: 'com.hazelcast', version: '5.6.0') {

entry 'hazelcast'

}

// Documentation must be updated if mssql-jdbc is updated: https://github.com/SonarSource/sonarqube/commit/03e4773ebf6cba854cdcf57a600095f65f4f53e7

dependency('com.microsoft.sqlserver:mssql-jdbc:13.4.0.jre11') {

exclude 'com.fasterxml.jackson.core:jackson-databind'

}

dependency 'com.microsoft.azure:msal4j:1.24.0'

dependency 'com.oracle.database.jdbc:ojdbc11:23.26.1.0.0'

dependency 'org.aspectj:aspectjtools:1.9.25.1'

dependencySet(group: 'com.squareup.okhttp3', version: '5.3.2') {

entry 'okhttp'

entry 'okhttp-jvm'

entry 'mockwebserver'

entry 'okhttp-tls'

entry 'logging-interceptor'

}

dependency 'commons-logging:commons-logging:1.3.6'

dependency 'org.json:json:20250517'

// To be removed after migration to JUnit5 is finished

dependency 'com.tngtech.java:junit-dataprovider:1.13.1'

dependency 'com.tngtech.junit.dataprovider:junit-jupiter-params-dataprovider:2.12'

dependencySet(group: 'io.jsonwebtoken', version: '0.13.0') {

entry 'jjwt-api'

entry 'jjwt-impl'

entry 'jjwt-jackson'

}

dependency 'com.auth0:java-jwt:4.5.1'

dependency 'io.netty:netty-all:4.2.12.Final'

dependency 'jakarta.mail:jakarta.mail-api:2.1.5'

dependency 'jakarta.annotation:jakarta.annotation-api:3.0.0'

dependency 'jakarta.inject:jakarta.inject-api:2.0.1'

dependency 'jakarta.servlet:jakarta.servlet-api:6.1.0'

dependency 'junit:junit:4.13.2'

dependencySet(group: 'org.xmlunit', version: '2.11.0') {

entry 'xmlunit-core'

entry 'xmlunit-matchers'

}

dependency 'at.yawk.lz4:lz4-java:1.10.4'

dependency 'org.littleshoot:littleproxy:1.1.2'

dependency 'net.sf.trove4j:core:3.1.0'

dependency 'org.awaitility:awaitility:4.3.0'

dependency 'org.apache.commons:commons-csv:1.14.1'

dependency 'org.apache.commons:commons-lang3:3.20.0'

dependency 'org.apache.commons:commons-email2-jakarta:2.0.0-M1'

dependency 'org.apache.commons:commons-exec:1.6.0'

dependency 'org.apache.commons:commons-text:1.15.0'

dependencySet(group: 'org.apache.kerby', version: '2.1.1') {

entry 'kerb-simplekdc'

entry 'ldap-backend'

}

dependency 'org.apache.mina:mina-core:2.2.5'

dependency 'com.zaxxer:HikariCP:7.0.2'

dependency('org.apache.directory.server:apacheds-server-integ:2.0.0.AM27') {

exclude 'log4j:log4j'

}

// Be aware that Log4j is used by Elasticsearch client

dependencySet(group: 'org.apache.logging.log4j', version: '2.25.4') {

entry 'log4j-core'

entry 'log4j-api'

entry 'log4j-to-slf4j'

}

dependencySet(group: 'org.apache.tomcat.embed', version: '11.0.20') {

entry 'tomcat-embed-core'

entry('tomcat-embed-jasper') {

exclude 'org.eclipse.jdt.core.compiler:ecj'

}

}

//transitive dependency of SVNKit, to be re-assessed when updating SVNKit

dependency 'org.apache.sshd:sshd-core:2.17.1'

dependencySet(group: 'org.assertj', version: '3.27.7') {

entry 'assertj-core'

entry 'assertj-guava'

}

dependencySet(group: 'org.bouncycastle', version: '1.83') {

entry 'bcpkix-jdk18on'

entry 'bcprov-jdk18on'

}

dependency('org.codehaus.sonar:sonar-channel:4.2') {

exclude 'org.slf4j:slf4j-api'

}

dependency 'org.cyclonedx:cyclonedx-core-java:12.1.0'

dependency 'com.fasterxml.staxmate:staxmate:2.4.1'

// Old Elasticsearch REST High Level Client (7.x) - Keep temporarily for compatibility

dependency("org.elasticsearch.client:elasticsearch-rest-high-level-client:${elasticSearchClientVersion}") {

exclude 'org.apache.logging.log4j:log4j-core'

}

dependency "org.elasticsearch.plugin:transport-netty4-client:${elasticSearchClientVersion}"

dependency 'org.elasticsearch:mocksocket:1.2'

// New Elasticsearch Java API Client (8.x) - For migration

dependency "co.elastic.clients:elasticsearch-java:${elasticSearchJavaClientVersion}"

dependency 'org.eclipse.jgit:org.eclipse.jgit:7.6.0.202603022253-r'

dependency "org.codelibs.elasticsearch.module:analysis-common:7.17.22"

dependency "org.codelibs.elasticsearch.module:reindex:7.17.22"

dependency('org.tmatesoft.svnkit:svnkit:1.10.11')

dependency 'org.hamcrest:hamcrest:3.0'

dependency 'org.jsoup:jsoup:1.22.1'

// JUnit 5

imports { mavenBom 'org.junit:junit-bom:6.0.3' }

dependency 'org.junit-pioneer:junit-pioneer:2.3.0'

dependencySet(group: 'org.mockito', version: '5.23.0') {

entry 'mockito-core'

entry('mockito-junit-jupiter') {

exclude 'org.junit.jupiter:junit-jupiter-api'

}

}

dependency 'org.spdx:java-spdx-library:2.0.2'

dependency 'org.spdx:spdx-v3jsonld-store:1.0.4'

dependency 'org.spdx:spdx-jackson-store:2.0.3'

dependencySet(group: 'org.springframework', version: '7.0.6') {

entry 'spring-test'

entry 'spring-context'

entry 'spring-webmvc'

}

dependencySet(group: 'org.springframework.security', version: "${springSecurityVersion}") {

entry 'spring-security-config'

entry 'spring-security-core'

entry 'spring-security-web'

entry 'spring-security-saml2-service-provider'

}

dependency 'org.mybatis:mybatis:3.5.19'

dependencySet(group: 'org.slf4j', version: '2.0.17') {

entry 'jcl-over-slf4j'

entry 'jul-to-slf4j'

entry 'log4j-over-slf4j'

entry 'slf4j-api'

}

dependency 'org.postgresql:postgresql:42.7.10'

dependency 'org.reflections:reflections:0.10.2'

dependency 'org.simpleframework:simple:5.1.6'

dependency 'org.sonarsource.git.blame:git-files-blame:2.0.2.54'

dependencySet(group: 'org.sonarsource.orchestrator', version: '6.1.0.3962') {

entry('sonar-orchestrator-junit4') {

exclude 'com.fasterxml.jackson.dataformat:jackson-dataformat-xml'

}

entry('sonar-orchestrator-junit5') {

exclude 'com.fasterxml.jackson.dataformat:jackson-dataformat-xml'

}

}

dependency "com.sonarsource.pdfreport:portfolio-report-pdf-generation:${pdfreportVersion}"

dependency "com.sonarsource.pdfreport:regulatory-report-pdf-generation:${pdfreportVersion}"

dependency "com.sonarsource.pdfreport:security-report-pdf-generation:${pdfreportVersion}"

dependency "com.sonarsource.pdfreport:pdf-generator-utils:${pdfreportVersion}"

dependency 'com.sonarsource.fixsuggestions:ai-suggestions-shared:1.0.0.1775'

dependencySet(group: 'dev.langchain4j', version: '1.12.2') {

entry 'langchain4j-azure-open-ai'

entry 'langchain4j-bedrock'

entry 'langchain4j-http-client-jdk'

entry 'langchain4j-open-ai'

}

dependency 'software.amazon.awssdk:apache-client:2.42.24'

dependency 'org.sonarsource.update-center:sonar-update-center-common:1.36.0.4317'

dependency 'org.sonarsource.classloader:sonar-classloader:1.2.1.2095'

dependency 'org.springdoc:springdoc-openapi-starter-webmvc-api:3.0.2'

dependencySet(group: 'com.icegreen', version: '2.1.8') {

entry 'greenmail'

entry 'greenmail-junit4'

entry 'greenmail-junit5'

}

dependency 'org.yaml:snakeyaml:2.6'

dependency 'org.hibernate.validator:hibernate-validator:9.1.0.Final'

dependency 'org.kohsuke:github-api:1.330'

dependency 'org.wiremock:wiremock-standalone:3.13.2'

dependency 'org.skyscreamer:jsonassert:1.5.3'

// to be used only in sonar-ws-generator

dependency 'org.apache.velocity:velocity-engine-core:2.4.1'

dependency 'com.google.code.findbugs:jsr305:3.0.2'

// Scanner Engine

dependencySet(group: 'com.sonarsource.scanner.engine', version: "${scannerEngineVersion}") {

entry 'scanner-engine-community'

entry 'scanner-engine-protocol-server'

entry 'protobuf-utils'

}

}

}

tasks.withType(Javadoc) {

options.addStringOption('Xdoclint:none', '-quiet')

options.encoding = 'UTF-8'

title = project.name + ' ' + versionWithoutBuildNumber

}

tasks.withType(Test) {

if (System.getenv().containsKey("GITHUB_ACTIONS")) {

develocity.testRetry {

maxRetries = 3

maxFailures = 30

failOnPassedAfterRetry = System.getenv("GITHUB_REF_NAME") != "master"

}

}

}

task sourcesJar(type: Jar, dependsOn: classes) {

archiveClassifier = 'sources'

from sourceSets.main.allSource

}

task javadocJar(type: Jar, dependsOn: javadoc) {

archiveClassifier = 'javadoc'

from javadoc.destinationDir

}

// generate code before opening project in IDE (Eclipse or Intellij)

task ide() {

// empty by default. Dependencies are added to the task

// when needed (see protobuf modules for example)

}

task generatePackageInfo {

doLast {

def allPathsContainingJavaFiles = [] as Set

fileTree('src/main/java/').matching() {

include "*/**/*.java"

exclude "*/**/package-info.java"

}.forEach {

allPathsContainingJavaFiles << it.toPath().toFile().getParent();

}

allPathsContainingJavaFiles.each {

String packageInfoPath = it + "/package-info.java"

File packageInfoFile = new File(packageInfoPath)

if (!packageInfoFile.exists()) {

logger.info("Creating file: " + packageInfoPath)

def packageName = packageInfoFile.getParent().replaceAll("[\\\\ /]", ".").takeAfter("src.main.java.");

String packageInfoContent = applyPackageInfoTemplate(packageName)

packageInfoFile << packageInfoContent

}

}

def allPackageInfoFiles = [] as Set

fileTree('src/main/java/').matching() {

include "*/**/package-info.java"

}.forEach {

allPackageInfoFiles << it.toPath().toFile();

}

allPackageInfoFiles.forEach {

File packageInfoFile = it;

if (!allPathsContainingJavaFiles.contains(packageInfoFile.getParent())) {

logger.warn("Deleting package info file: " + packageInfoFile)

packageInfoFile.delete();

}

}

}

}

build.dependsOn(generatePackageInfo)

generatePackageInfo.finalizedBy(licenseFormat)

jacocoTestReport {

reports {

xml.required = true

csv.required = false

html.required = false

}

}

normalization {

runtimeClasspath {

// Following classpath resources contain volatile data that changes in each CI build (build number, commit id, time),

// so we exclude them from calculation of build cache key of test tasks:

ignore 'META-INF/MANIFEST.MF'

ignore 'sonar-api-version.txt'

ignore 'sq-version.txt'

}

}

ext.failedTests = []

test {

jvmArgs '-Dfile.encoding=UTF8'

maxHeapSize = '1500m'

systemProperty 'java.awt.headless', true

// Some tests are asserting on localized messages or dates

systemProperty 'user.language', 'en'

systemProperty 'user.country', 'US'

environment 'LANGUAGE', 'en_US'

testLogging {

events "skipped", "failed" // verbose log for failed and skipped tests (by default the name of the tests are not logged)

exceptionFormat 'full' // log the full stack trace (default is the 1st line of the stack trace)

}

jacoco {

enabled = true // do not disable recording of code coverage, so that remote Gradle cache entry can be used locally

includes = ['com.sonar.*', 'com.sonarsource.*', 'org.sonar.*', 'org.sonarqube.*', 'org.sonarsource.*']

}

if (project.hasProperty('maxParallelTests')) {

maxParallelForks = project.maxParallelTests as int

}

if (project.hasProperty('parallelTests')) {

// See https://guides.gradle.org/performance/#parallel_test_execution

maxParallelForks = Runtime.runtime.availableProcessors().intdiv(2) ?: 1

}

afterTest { descriptor, result ->

if (result.resultType == TestResult.ResultType.FAILURE) {

String failedTest = " ${descriptor.className} > ${descriptor.name}"

failedTests << failedTest

}

}

}

gradle.buildFinished {

if (!failedTests.empty) {

println "\nFailed tests:"

failedTests.each { failedTest ->

println failedTest

}

println ""

}

}

def protoMainSrc = 'src/main/protobuf'

def protoTestSrc = 'src/test/protobuf'

if (file(protoMainSrc).exists() || file(protoTestSrc).exists()) {

// protobuf must be applied after java

apply plugin: 'com.google.protobuf'

sourceSets.main.proto.srcDir protoMainSrc // in addition to the default 'src/main/proto'

sourceSets.test.proto.srcDir protoTestSrc // in addition to the default 'src/test/proto'

protobuf {

protoc {

artifact = "com.google.protobuf:protoc:${protobufVersion}"

}

}

jar {

exclude('**/*.proto')

}

idea {

module {

sourceDirs += file("${protobuf.generatedFilesBaseDir}/main/java")

testSourceDirs += file("${protobuf.generatedFilesBaseDir}/test/java")

generatedSourceDirs += file("${protobuf.generatedFilesBaseDir}/main/java")

generatedSourceDirs += file("${protobuf.generatedFilesBaseDir}/test/java")

}

}

ide.dependsOn(['generateProto', 'generateTestProto'])

}

if (official) {

jar {

// do not break incremental build on non official versions

manifest {

attributes(

'Version': "${version}",

'Implementation-Build': System.getenv('GITHUB_SHA'),

'Build-Time': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")

)

}

}

}

license {

header = rootProject.file('HEADER')

ignoreFailures = project.hasProperty('ignoreLicenseFailures') ? project.getProperty('ignoreLicenseFailures').toBoolean() : true

strictCheck true

encoding = 'UTF-8'

mapping {

java = 'SLASHSTAR_STYLE'

js = 'SLASHSTAR_STYLE'

ts = 'SLASHSTAR_STYLE'

tsx = 'SLASHSTAR_STYLE'

css = 'SLASHSTAR_STYLE'

}

includes(['**/*.java', '**/*.js', '**/*.ts', '**/*.tsx', '**/*.css'])

}

tasks.withType(GenerateModuleMetadata) {

enabled = false

}

publishing {

publications {

mavenJava(MavenPublication) {

pom {

name = 'SonarQube'

description = project.description

url = 'https://www.sonarsource.com/products/sonarqube'

organization {

name = 'SonarSource'

url = 'https://www.sonarsource.com'

}

licenses {

license {

name = 'GNU LGPL 3'

url = 'http://www.gnu.org/licenses/lgpl.txt'

distribution = 'repo'

}

}

scm {

url = 'https://github.com/SonarSource/sonarqube'

}

developers {

developer {

id = 'sonarsource-team'

name = 'SonarSource Team'

}

}

}

}

}

}

tasks.withType(BlackBoxTest) {

jacoco.enabled = false

testClassesDirs = sourceSets.bbt.output.classesDirs

classpath = sourceSets.bbt.runtimeClasspath

configurations {

includeInTestResources

}

dependencies {

bbtRuntimeOnly 'com.microsoft.sqlserver:mssql-jdbc'

bbtRuntimeOnly 'com.oracle.database.jdbc:ojdbc11'

bbtRuntimeOnly 'org.postgresql:postgresql'

bbtRuntimeOnly project(':plugins:sonar-xoo-plugin')

bbtImplementation 'org.sonarsource.orchestrator:sonar-orchestrator-junit4'

bbtImplementation project(":sonar-testing-harness")

bbtImplementation project(":private:it-common")

bbtImplementation testFixtures(project(":sonar-ws"))

}

}

signing {

def signingKeyId = findProperty("signingKeyId")

def signingKey = findProperty("signingKey")

def signingPassword = findProperty("signingPassword")

useInMemoryPgpKeys(signingKeyId, signingKey, signingPassword)

required {

return isMainBranch && gradle.taskGraph.hasTask(":artifactoryPublish")

}

sign publishing.publications

}

tasks.withType(Sign) {

onlyIf {

return !artifactoryPublish.skip && isMainBranch && gradle.taskGraph.hasTask(":artifactoryPublish")

}

}

}

static def applyPackageInfoTemplate(packageName) {

def engine = new SimpleTemplateEngine()

def templateText = "@ParametersAreNonnullByDefault\n" +

"package $packageName;\n" +

"\n" +

"import javax.annotation.ParametersAreNonnullByDefault;\n"

def templateParams = ["packageName": packageName]

engine.createTemplate(templateText).make(templateParams).toString()

}

gradle.projectsEvaluated { gradle ->

// yarn_run tasks can't all run in parallel without random issues

// this script ensure all yarn_run tasks run sequentially

def yarnRunTasks = allprojects.findResults { it -> it.tasks.findByName('yarn_run') }

yarnRunTasks.drop(1).eachWithIndex { it, i -> it.mustRunAfter(yarnRunTasks[0..i]) }

}

ext.osAdaptiveCommand = { commands ->

def newCommands = []

if (System.properties['os.name'].toLowerCase().contains('windows')) {

newCommands = ['cmd', '/c']

}

newCommands.addAll(commands)

return newCommands

}