@ECHO OFF

SET CMD_DIR=%~dp0

SET CMD_DIR=%CMD_DIR:~0,-1%

SET CALC_PATH=%CMD_DIR%\..\cmake\CalculateEnginePathId.cmake

FOR /F %%g IN ('cmake -P "%CALC_PATH%" "%CMD_DIR%\.."') DO SET ENGINE_ID=%%g

IF NOT "%ENGINE_ID%" == "" GOTO ENGINE_ID_CALCULATED

echo Unable to calculate engine ID

exit /b 1

:ENGINE_ID_CALCULATED

IF "" == "%LY_3RDPARTY_PATH%" (

SET LY_3RDPARTY_PATH=%USERPROFILE%\.o3de\3rdParty

)

SET PYTHON_VENV=%USERPROFILE%\.o3de\Python\venv\%ENGINE_ID%

SET PYTHON_VENV_ACTIVATE=%PYTHON_VENV%\Scripts\activate.bat

SET PYTHON_VENV_DEACTIVATE=%PYTHON_VENV%\Scripts\deactivate.bat

IF [%1] EQU [debug] (

SET PYTHON_VENV_PYTHON=%PYTHON_VENV%\Scripts\python_d.exe

SET PYTHON_ARGS=%*:~6%

) ELSE (

SET PYTHON_VENV_PYTHON=%PYTHON_VENV%\Scripts\python.exe

SET PYTHON_ARGS=%*

)

IF EXIST "%PYTHON_VENV_PYTHON%" GOTO PYTHON_VENV_EXISTS

ECHO Python has not been setup completely for O3DE. Missing Python venv %PYTHON_VENV_PYTHON%

ECHO Try running %CMD_DIR%\get_python.bat to setup Python for O3DE.

exit /b 1

:PYTHON_VENV_EXISTS

FOR /F %%g IN ('cmake -P "%CMD_DIR%\get_python_package_hash.cmake" "%CMD_DIR%\.." Windows') DO SET CURRENT_PACKAGE_HASH=%%g

IF NOT "%CURRENT_PACKAGE_HASH%" == "" GOTO PACKAGE_HASH_READ

echo Unable to get current python package hash

exit /b 1

:PACKAGE_HASH_READ

SET PYTHON_VENV_HASH=%PYTHON_VENV%\.hash

IF EXIST "%PYTHON_VENV_HASH%" GOTO PYTHON_VENV_HASH_EXISTS

ECHO Python has not been setup completely for O3DE. Missing venv hash %PYTHON_VENV_HASH%

ECHO Try running %CMD_DIR%\get_python.bat to setup Python for O3DE.

exit /b 1

:PYTHON_VENV_HASH_EXISTS

SET /p VENV_PACKAGE_HASH=<"%PYTHON_VENV_HASH%"

IF "%VENV_PACKAGE_HASH%" == "%CURRENT_PACKAGE_HASH%" GOTO PYTHON_VENV_MATCHES

ECHO Python needs to be updated against the current version.

ECHO Try running %CMD_DIR%\get_python.bat to update Python for O3DE.

exit /b 1

:PYTHON_VENV_MATCHES

call "%PYTHON_VENV_ACTIVATE%"

call "%PYTHON_VENV_PYTHON%" -B %PYTHON_ARGS%

SET PYTHON_RESULT=%ERRORLEVEL%

call "%PYTHON_VENV_DEACTIVATE%"

exit /B %PYTHON_RESULT%