Skip to content
Navigation Menu
{{ message }}
-
Notifications
You must be signed in to change notification settings - Fork 0
Expand file tree
/
Copy pathsodbc2schdb.pls
More file actions
445 lines (428 loc) · 15 KB
/
sodbc2schdb.pls
File metadata and controls
445 lines (428 loc) · 15 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
*****************************************************
. sqlite schema initialization sample program
. creates a runtime schema from a sunodbc schema
.
. By: Matthew Lake
. Copyright 2010 Sunbelt Computer Systems, Inc.
.
. 9.4A corrected some bugs that prevented it from running
. "out of the box".
*****************************************************
.
. This loadmod has two calls, one to initialize a schema database and
. one to import a SunODBC schema.
.
. To use this module, call initialize passing in the name of the
. schema database you would like to use. If one is not specified, it
. uses the default sunschema.db that is automatically created by the
. runtime.
.
. After calling initialize, call the ImportFromODBCSchema function
. passing in the name of the SunODBC schema.ini file.
.
. Syntax:
.
. CALLS "sodbc2schdb;INITIALIZE" using schemaDBname
. CALLS "sodbc2schdb;IMPORTFROMODBCSCHEMA" using odbcschema
.
. Where:
. schemaDBname optional DIM variable containing the sqlite db name to
. use to contain the runtime schema information
.
. odbcschema required dim variable containing the sunodbc schema.ini
. filename
.
. Example Code:
.
fname DIM 60
fpath DIM 200
odbcschema DIM 260
GETFNAME OPEN,"Select ODBC Schema.ini file",fname,fpath,"ini"
PACK odbcschema,fpath,fname
.
CALL INITIALIZE // USING "c:\sunbelt\plbwin.95\code\sunschema.db"
CALL ImportFromODBCSchema using odbcschema
.
STOP
.
.***************************************************************************
. Loadmod begins here...
.***************************************************************************
.
db DBFILE
tm FORM "5"
.
INITIALIZE FUNCTION
schemadb DIM 260
ENTRY
haveView FORM 1
havecolumns FORM 1
havedatabases FORM 1
field DIM 80
sys DIM 250
host DIM 300
.
. initialize schema database
.
TYPE schemadb
IF EOS
MOVE "PLB_SYSTEM",sys
CLOCK INI,sys
IF OVER
CLEAR sys
ELSE
ENDSET sys
CMATCH "\",sys
IF NOT EQUAL
APPEND "\",sys
ENDIF
RESET sys
ENDIF
PACK schemadb,sys,"sunschema.db"
ENDIF
.
PACK host,"SQLITE;;",schemadb
DBCONNECT db,host,"",""
.
. get existing table definitions
.
DBSEND db;"SELECT name FROM sqlite_master ":
"WHERE type='table' ":
"ORDER BY name;"
DBEXECUTE db
LOOP
DBSTATE db
UNTIL NOT LESS
REPEAT
. figure out what is there
LOOP
DBFETCH db,tm;field
UNTIL OVER
LOWERCASE field
SWITCH field
CASE "sun_views"
SET haveview
CASE "sun_databases"
SET havedatabases
CASE "sun_columns"
SET havecolumns
ENDSWITCH
REPEAT
. create missing tables
IF ( !haveview )
DBSEND db;"CREATE TABLE sun_views ( id integer, name text not null unique, description text );"
DBEXECUTE db
LOOP
DBSTATE db
UNTIL NOT LESS
REPEAT
ENDIF
IF ( !havecolumns )
DBSEND db;"CREATE TABLE sun_columns ( id integer primary key, ":
"view_id integer, ":
"name text not null,":
"description text,":
"type integer,":
"offset integer,":
"length integer,":
"scale integer,":
"element_count integer,":
"sql_type integer,":
"key_value integer,":
"nullable integer,":
"zero_fill integer,":
"empty_null integer,":
"selectivity integer,":
"format_mask text,":
"default_value text );"
DBEXECUTE db
LOOP
DBSTATE db
UNTIL NOT LESS
REPEAT
ENDIF
IF ( !havedatabases )
DBSEND db;"CREATE TABLE sun_databases ":
"( id integer, name text, databasefile text );"
DBEXECUTE db
LOOP
DBSTATE db
UNTIL NOT LESS
REPEAT
ENDIF
FUNCTIONEND
GETNEXTVIEWID FUNCTION
ENTRY
nextid FORM 4
DBSEND db;"SELECT MAX(id) FROM sun_views"
DBEXECUTE db
LOOP
DBSTATE db
UNTIL NOT LESS
REPEAT
DBFETCH db,tm;nextid
INCR nextid
FUNCTIONEND USING nextid
GETNEXTCID FUNCTION
ENTRY
nextid FORM 4
DBSEND db;"SELECT MAX(id) FROM sun_columns"
DBEXECUTE db
LOOP
DBSTATE db
UNTIL NOT LESS
REPEAT
DBFETCH db,tm;nextid
INCR nextid
FUNCTIONEND USING nextid
GETIDOFVIEW FUNCTION
vname DIM 80
ENTRY
sql DIM 200
vid FORM 4
CHOP vname
PACK sql,"SELECT id FROM sun_views WHERE name LIKE '",vname,"';"
DBSEND db;sql
DBEXECUTE db
LOOP
DBSTATE db
UNTIL NOT LESS
REPEAT
DBFETCH db,tm;vid
IF OVER
MOVE "-1",vid
ENDIF
.
FUNCTIONEND USING vid
ImportFromODBCSchema FUNCTION
fname DIM 250
ENTRY
FILE FILE
SEQ FORM "-1"
data DIM 1000
vname DIM 80
sql DIM 1000
vid FORM 4
vidd DIM 4
.
cid FORM 4
cidd DIM 4
cname DIM 80
otype DIM 30
ctype DIM 1
csize FORM 4 //column size
csized DIM 4
coffset FORM 10 //column offset
coffsetd DIM 10
cscale FORM 2
cscaled DIM 2
mask DIM 25
fm4 FORM 4
.
zf DIM 1
null DIM 1
primary DIM 1
res DIM 10
.
. quick notes
. sunodbc schema file mappings:
. [tables] = sun_views
. [{tablename}] = sun_columns where {tablename} is view_id
. ( foreighn key to sun_views.id )
.
.
OPEN file,fname,read
LOOP
READ file,seq;data
UNTIL OVER
UPPERCASE data
.
. put together the views table
.
MATCH "[TABLES]",data
IF EQUAL
LOOP
READ file,seq;data
UNTIL OVER
MATCH "[",data
BREAK IF EQUAL
EXPLODE data,"=",vname
..
CALL GETIDOFVIEW giving vid using vname
CONTINUE IF (vid!="-1") // view already exists!!
..
CALL GETNEXTVIEWID giving vid
MOVE vid,vidd
SQUEEZE vidd,vidd
PACK sql,"INSERT INTO sun_views (id,name) VALUES('",vidd,"','",vname,"');"
DBSEND db;sql
DBEXECUTE db
LOOP
DBSTATE db
UNTIL NOT LESS
REPEAT
REPEAT
ENDIF
.
. build columns table
.
MATCH "[",data
IF EQUAL
nxt_tbl MOVE "1",coffset // each table offset starts at 1
.
. get the view and view_id
.
BUMP data
EXPLODE data,"]",vname
CALL GETIDOFVIEW giving vid using vname
CONTINUE IF (vid="-1") //column not found in views
MOVE vid,vidd
SQUEEZE vidd,vidd
.
LOOP
READ file,seq;data
UNTIL over
.
. open bracket is start of next view
MATCH "[",data
GOTO nxt_tbl IF EQUAL
.
UPPERCASE data
MATCH "COL",data
CONTINUE IF NOT EQUAL
.
. get column ID
BUMP data,3
PARSE data,cidd,"09"
MOVE cidd,cid
BUMP data
.
PARSE data,cname,"AZ" //column name
..
.. does column already exist in view?
..
PACK sql,"SELECT id FROM sun_columns WHERE view_id='",vidd,"' AND name LIKE '",cname,"';"
DBSEND db;sql
DBEXECUTE db
LOOP
DBSTATE db
UNTIL NOT LESS
REPEAT
IF ZERO
. if the select returned any data, we have a problem
DBFETCH db,tm;fm4
BREAK IF NOT OVER
ENDIF
..
.. Get next available ID
..
CALL GETNEXTCID giving cid
..
PARSE data,otype,"AZ09" //column type or res num
IF LESS // reached end of definition,
CLEAR mask //assume we got column type and no mask
ELSE
TYPE otype
IF EQUAL
MOVE otype,res // got restriction number
PARSE data,otype,"AZ" // get column type next
ELSE
MOVE "0",res
ENDIF
..
PARSE data,mask,"AZ//''" //"Width" or mask
ENDIF
CLEAR cscale
.
SWITCH otype
CASE "INTEGER"
MOVE "1",ctype //form
MOVE "0",cscale
PARSE data,csized,"09"
MOVE csized,csize
.
CASE "FLOAT"
MOVE "1",ctype //form
PARSE data,csized,"09.."
EXPLODE csized,".",csize,cscale
.
CASE "DATE"
NOBREAK
CASE "TIME"
NOBREAK
CASE "TIMESTAMP"
MOVE "0",ctype //dim
TYPE mask
IF NOT EOS
COUNT csize,mask
SUB "2",csize // compensate for quotes
ELSE
IF (ctype="TIMESTAMP")
MOVE "14",csize
ELSE
MOVE "8",csize
ENDIF
ENDIF
.
DEFAULT
MOVE "0",ctype //dim
PARSENUM data,csize
ENDSWITCH
.
.. get ODBC Options from remainder of column data
WHEREIS "NULL",data
IF NOT ZERO
MOVE "1",null
ELSE
MOVE "0",null
ENDIF
.
WHEREIS "PRIMARY",data
IF NOT ZERO
MOVE "1",primary
ELSE
MOVE "0",primary
ENDIF
.
WHEREIS "ZF",data
IF NOT ZERO
MOVE "1",zf
ELSE
WHEREIS "ZEROFILL",data
IF NOT ZERO
MOVE "1",zf
ELSE
MOVE "0",zf
ENDIF
ENDIF
..
MOVE coffset,coffsetd
.
ADD cscale,csize
IF (CSCALE) // decimal point
ADD "1",csize
ENDIF
.
. pack up data for SQL statement
.
ADD csize,coffset
MOVE csize,csized
MOVE cscale,cscaled
MOVE cid,cidd
SQUEEZE cidd,cidd
SQUEEZE coffsetd,coffsetd
SQUEEZE csized,csized
SQUEEZE cscaled,cscaled
PACK sql,"INSERT INTO sun_columns ":
"values ":
"(",cidd,",",vidd,",'",cname,"','',",ctype,",",coffsetd,",",csized,",",cscaled,",1,0,",primary,",0,",zf,",",null,",",res,",'','');"
DBSEND db;sql
DBEXECUTE db
LOOP
DBSTATE db
UNTIL NOT LESS
REPEAT
REPEAT
ENDIF
REPEAT
FUNCTIONEND
You can’t perform that action at this time.
