import net.fabricmc.loom.api.LoomGradleExtensionAPI

plugins {

id("architectury-plugin") version "3.4-SNAPSHOT"

id("dev.architectury.loom") version "1.10-SNAPSHOT" apply false

id("com.gradleup.shadow") version "8.3.6" apply false

kotlin("jvm") version ("2.1.20")

java

idea

`maven-publish`

}

val minecraftVersion = project.properties["minecraft_version"] as String

architectury.minecraft = minecraftVersion

allprojects {

version = project.properties["mod_version"] as String

group = project.properties["maven_group"] as String

}

subprojects {

apply(plugin = "dev.architectury.loom")

apply(plugin = "architectury-plugin")

apply(plugin = "maven-publish")

apply(plugin = "org.jetbrains.kotlin.jvm")

base.archivesName.set(project.properties["archives_base_name"] as String + "-${project.name}")

val loom = project.extensions.getByName<LoomGradleExtensionAPI>("loom")

loom.silentMojangMappingsLicense()

loom.mixin.useLegacyMixinAp.set(false)

repositories {

mavenCentral()

mavenLocal()

maven("https://repo1.maven.org/maven2")

maven("https://jitpack.io")

maven("https://maven.generations.gg/snapshots")

maven("https://maven.generations.gg/releases")

maven("https://pkgs.dev.azure.com/djtheredstoner/DevAuth/_packaging/public/maven/v1")

maven("https://cursemaven.com").content { includeGroup("curse.maven") }

maven("https://api.modrinth.com/maven").content { includeGroup("maven.modrinth") }

maven("https://maven.impactdev.net/repository/development/")

maven("https://maven.parchmentmc.org")

maven("https://maven2.bai.lol").content {

includeGroup("lol.bai")

includeGroup("mcp.mobius.waila")

}

maven("https://maven.tterrag.com/")

maven("https://nexus.resourcefulbees.com/repository/maven-public/")

maven("https://maven.neoforged.net/releases")

maven("https://jm.gserv.me/repository/maven-public/")

maven(

// location of the maven that hosts JEI files since January 2023

url = "https://maven.blamejared.com/"

)

}

@Suppress("UnstableApiUsage")

dependencies {

"minecraft"("com.mojang:minecraft:$minecraftVersion")

"mappings"(loom.layered{

officialMojangMappings()

parchment("org.parchmentmc.data:parchment-$minecraftVersion:${project.properties["parchment"]}@zip")

})

compileOnly("org.jetbrains:annotations:26.0.2")

}

java {

withSourcesJar()

sourceCompatibility = JavaVersion.VERSION_17

targetCompatibility = JavaVersion.VERSION_17

}

tasks.withType<JavaCompile>().configureEach {

options.release.set(17)

}

kotlin.jvmToolchain(17)

publishing {

publications.create<MavenPublication>("mavenJava") {

artifactId = base.archivesName.get()

from(components["java"])

}

repositories {

mavenLocal()

maven {

val releasesRepoUrl = "https://maven.generations.gg/releases"

val snapshotsRepoUrl = "https://maven.generations.gg/snapshots"

url = uri(if (project.version.toString().endsWith("SNAPSHOT") || project.version.toString().startsWith("0")) snapshotsRepoUrl else releasesRepoUrl)

name = "Generations-Repo"

credentials {

username = getGensCredentials().first

password = getGensCredentials().second

}

}

}

}

}

private fun getGensCredentials(): Pair<String?, String?> {

val username = (project.findProperty("gensUsername") ?: System.getenv("GENS_USERNAME") ?: "") as String?

val password = (project.findProperty("gensPassword") ?: System.getenv("GENS_PASSWORD") ?: "") as String?

return Pair(username, password)

}