Skip to content
Navigation Menu
{{ message }}
-
Notifications
You must be signed in to change notification settings - Fork 2
Expand file tree
/
Copy pathStringTools.bas
More file actions
432 lines (389 loc) · 15 KB
/
StringTools.bas
File metadata and controls
432 lines (389 loc) · 15 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
Attribute VB_Name = "StringTools"
Attribute VB_Description = "String-Hilfsfunktionen"
'---------------------------------------------------------------------------------------
' Package: text.StringTools
'---------------------------------------------------------------------------------------
'
' Text functions
'
' Author:
' Josef Poetzl, Sten Schmidt
'
' Remarks:
' Use DisableReplaceVbaStringFunctions = 1 in conditional compilation arguments (in vbe project properties)
' to disable replacement of VBA.Format function
'
'---------------------------------------------------------------------------------------
'---------------------------------------------------------------------------------------
'<codelib>
' <file>text/StringTools.bas</file>
' <license>_codelib/license.bas</license>
' <test>_test/text/StringToolsTests.cls</test>
'</codelib>
'---------------------------------------------------------------------------------------
'
Option Compare Text
Option Explicit
Option Private Module
'---------------------------------------------------------------------------------------
' Enum: TrimOption
'---------------------------------------------------------------------------------------
'
' Available trim options for the trim function
'
' TrimStart - (1) Remove leading spaces from a string variable
' TrimEnd - (2) Remove trailing spaces from a string variable
' TrimBoth - (3) Remove leading and trailing spaces
'
'---------------------------------------------------------------------------------------
Public Enum TrimOption
TrimStart = 1
TrimEnd = 2
TrimBoth = 3
End Enum
'---------------------------------------------------------------------------------------
' Function: IsNullOrEmpty
'---------------------------------------------------------------------------------------
'
' Specifies whether the passed value is null or an empty string
'
' Parameters:
' ValueToTest - Value to be checked
' IgnoreSpaces - Ignore spaces at the beginning and end
'
' Returns:
' Boolean
'
'---------------------------------------------------------------------------------------
Public Function IsNullOrEmpty(ByVal ValueToTest As Variant, Optional ByVal IgnoreSpaces As Boolean = False) As Boolean
Dim TempValue As String
If IsNull(ValueToTest) Then
IsNullOrEmpty = True
Exit Function
End If
TempValue = CStr(ValueToTest)
If IgnoreSpaces Then
TempValue = Trim$(TempValue)
End If
IsNullOrEmpty = (Len(TempValue) = 0)
End Function
'---------------------------------------------------------------------------------------
' Function: FormatText
'---------------------------------------------------------------------------------------
'
' Inserts the passed parameters into the placeholder {0..n} of the format text
'
' Parameters:
' FormatString - Text format with placeholder ... Example: "XYZ{0}, {1}"
' Args - Passing parameters in suitable order
'
' Returns:
' String
'
'---------------------------------------------------------------------------------------
Public Function FormatText(ByVal FormatString As String, ParamArray Args() As Variant) As String
Dim Arg As Variant
Dim Temp As String
Dim i As Long
#If USELOCALIZATION = 1 Then
FormatString = L10n.Text(FormatString)
#End If
Temp = FormatString
For Each Arg In Args
Temp = Replace(Temp, "{" & i & "}", CStr(Arg))
i = i + 1
Next
FormatText = Temp
End Function
'---------------------------------------------------------------------------------------
' Function: Format
'---------------------------------------------------------------------------------------
'
' Replaces the VBA format function
' Extension: [h] or [hh] for hour display over 24
'
' Parameters:
' Expression - The value to format
' FormatString - A valid named or user-defined format expression incl. extension for hours display over 24 (for standard format instructions see VBA.Format)
' FirstDayOfWeek - Passed on to VBA.Format
' FirstWeekOfYear - Passed on to VBA.Format
'
' Returns:
' String
'
'---------------------------------------------------------------------------------------
#If DisableReplaceVbaStringFunctions = 0 Then
Public Function Format(ByVal Expression As Variant, Optional ByVal FormatString As Variant, _
Optional ByVal FirstDayOfWeek As VbDayOfWeek = vbSunday, _
Optional ByVal FirstWeekOfYear As VbFirstWeekOfYear = vbFirstJan1) As String
Format = FormatX(Expression, FormatString, FirstDayOfWeek, FirstWeekOfYear)
End Function
#End If
Public Function FormatX(ByVal Expression As Variant, Optional ByVal FormatString As Variant, _
Optional ByVal FirstDayOfWeek As VbDayOfWeek = vbSunday, _
Optional ByVal FirstWeekOfYear As VbFirstWeekOfYear = vbFirstJan1) As String
Dim Hours As Long
If Not IsDate(Expression) Then
If IsNumeric(Expression) Then ' falls Zeitberechnung übergeben wird, ohne auf CDate zu konvertieren
If InStr(1, Replace(FormatString, "[hh]", "[h]"), "[h]") > 0 Then
Expression = CDate(Expression)
End If
End If
End If
If IsDate(Expression) Then
If InStr(1, FormatString, "[h", vbTextCompare) > 0 Then
Hours = Fix(Round(CDate(Expression) * 24, 1))
If Abs(Hours) < 24 Then
FormatString = Replace(FormatString, "[hh]", "hh", , , vbTextCompare)
FormatString = Replace(FormatString, "[h]", "h", , , vbTextCompare)
Else
FormatString = Replace(FormatString, "[hh]", "[h]", , , vbTextCompare)
FormatString = Replace(FormatString, "[h]", Replace(CStr(Hours), "0", "\0"), , , vbTextCompare)
End If
End If
End If
FormatX = VBA.Format$(Expression, FormatString, FirstDayOfWeek, FirstWeekOfYear)
End Function
'---------------------------------------------------------------------------------------
' Function: PadLeft
'---------------------------------------------------------------------------------------
'
' Left padding of a string
'
' Parameters:
' Value - String to be filled in
' TotalWidth - Total length of the resulting string
' PadChar - (optional) Character to be padded with; Default: " "
'
' Returns:
' String
'
' Remarks:
' If the length of value is greater than or equal to totalWidth, the result is limited to totalWidth characters
'
'---------------------------------------------------------------------------------------
Public Function PadLeft(ByVal Value As String, ByVal TotalWidth As Integer, Optional ByVal PadChar As String = " ") As String
PadLeft = VBA.Right$(VBA.String$(TotalWidth, PadChar) & Value, TotalWidth)
End Function
'---------------------------------------------------------------------------------------
' Function: PadRight
'---------------------------------------------------------------------------------------
'
' Right padding of a string
'
' Parameters:
' Value - String to be filled in
' TotalWidth - Total length of the resulting string
' PadChar - (optional) Character to be padded with; Default: " "
'
' Returns:
' String
'
' Remarks:
' If the length of value is greater than or equal to totalWidth, the result is limited to totalWidth characters
'
'---------------------------------------------------------------------------------------
Public Function PadRight(ByVal Value As String, ByVal TotalWidth As Integer, Optional ByVal PadChar As String = " ") As String
PadRight = VBA.Left$(Value & VBA.String$(TotalWidth, PadChar), TotalWidth)
End Function
'---------------------------------------------------------------------------------------
' Function: Contains
'---------------------------------------------------------------------------------------
'
' Indicates whether SearchValue occurs in the CheckValue string
'
' Parameters:
' CheckValue - String to be searched
' SearchValue - String to be searched for
'
' Returns:
' Boolean
'
' Remarks:
' Returns True if SearchValue is contained in CheckValue or SearchValue has the value vbNullString
'
'---------------------------------------------------------------------------------------
Public Function Contains(ByVal CheckValue As String, ByVal SearchValue As String) As Boolean
Contains = VBA.InStr(1, CheckValue, SearchValue, vbTextCompare) > 0
End Function
'---------------------------------------------------------------------------------------
' Function: EndsWith
'---------------------------------------------------------------------------------------
'
' Indicates whether the string CheckValue ends with SearchValue
'
' Parameters:
' CheckValue - String to be searched
' SearchValue - String to be searched for
'
' Returns:
' Boolean
'
'---------------------------------------------------------------------------------------
Public Function EndsWith(ByVal CheckValue As String, ByVal SearchValue As String) As Boolean
EndsWith = VBA.Right$(CheckValue, VBA.Len(SearchValue)) = SearchValue
End Function
'---------------------------------------------------------------------------------------
' Function: StartsWith
'---------------------------------------------------------------------------------------
'
' Indicates whether the string CheckValue starts with SearchValue
'
' Parameters:
' CheckValue - String to be searched
' SearchValue - String to be searched for
'
' Returns:
' Boolean
'
'---------------------------------------------------------------------------------------
Public Function StartsWith(ByVal CheckValue As String, ByVal SearchValue As String) As Boolean
StartsWith = VBA.Left$(CheckValue, VBA.Len(SearchValue)) = SearchValue
End Function
'---------------------------------------------------------------------------------------
' Function: Length
'---------------------------------------------------------------------------------------
'
' Returns the number of characters in Value
'
' Parameters:
' Value - String to be checked
'
' Returns:
' Long - Anzahl Zeichen von Value
'
'---------------------------------------------------------------------------------------
Public Function Length(ByVal Value As String) As Long
Length = VBA.Len(Value)
End Function
'---------------------------------------------------------------------------------------
' Function: Concat
'---------------------------------------------------------------------------------------
'
' Appends the string ValueB to the string ValueA.
'
' Parameters:
' ValueA - Base string
' ValueB - String to be append at end of A
'
' Returns:
' String - ValueB appended to ValueA
'
'---------------------------------------------------------------------------------------
Public Function Concat(ByVal ValueA As String, ByVal ValueB As String) As String
Concat = ValueA & ValueB
End Function
'---------------------------------------------------------------------------------------
' Function: Trim
'---------------------------------------------------------------------------------------
'
' Removes leading and/or trailing spaces from a string
'
' Replaces the function VBA.Trim().
'
' Parameters:
' Value - String to be trimmed
' TrimType - Trim options (at start, at end or both)
'
' Returns:
' String
'
'---------------------------------------------------------------------------------------
Public Function Trim(ByVal Value As String, Optional ByVal TrimType As TrimOption = TrimOption.TrimBoth) As String
Select Case TrimType
Case TrimOption.TrimBoth
Trim = VBA.Trim$(Value)
Exit Function
Case TrimOption.TrimStart
Trim = VBA.LTrim$(Value)
Exit Function
Case TrimOption.TrimEnd
Trim = VBA.RTrim(Value)
Exit Function
Case Else
Trim = Value
Exit Function
End Select
End Function
'---------------------------------------------------------------------------------------
' Function: Substring
'---------------------------------------------------------------------------------------
'
' Returns a part of the string Value starting at the position StartIndex and having the length Length.
'
' Parameters:
' Value - String
' StartIndex - Start position in the string
' Length - Number of characters to be returned
'
' Returns:
' String
'
' Remarks:
' StartIndex is null terminated, analogous to String.Substring() in .NET
'
'---------------------------------------------------------------------------------------
Public Function SubString(ByVal Value As String, ByVal StartIndex As Long, Optional ByVal Length As Long = 0) As String
If Length = 0 Then Length = StringTools.Length(Value) - StartIndex
SubString = VBA.Mid$(Value, StartIndex + 1, Length)
End Function
'---------------------------------------------------------------------------------------
' Function: InsertAt
'---------------------------------------------------------------------------------------
'
' Setzt die Zeichenfolge InsertValue an der Position Pos ein
'
' Parameters:
' Value - String
' InsertValue - String to be inserted
' Pos - Position at which the string is to be inserted (Pos is zero-terminated).
'
' Returns:
' String
'
'---------------------------------------------------------------------------------------
Public Function InsertAt(ByVal Value As String, ByVal InsertValue As String, ByVal Pos As Long) As String
InsertAt = VBA.Mid$(Value, 1, Pos) & InsertValue & StringTools.SubString(Value, Pos)
End Function
'---------------------------------------------------------------------------------------
' Function: Replicate
'---------------------------------------------------------------------------------------
'
' Repeat string
'
' Parameters:
' Value - The string to be repeated
' Number - Number of repetitions
'
' Returns:
' String
'
' Remarks:
' Replicate("abc", 3) creates "abcabcabc"
'
'---------------------------------------------------------------------------------------
Public Function Replicate(ByVal Value As String, ByVal Number As Long) As String
Dim ValueLen As Long
Dim TempString As String
Dim i As Long
If Number = 0 Then
Replicate = vbNullString
Exit Function
ElseIf Number = 1 Then
Replicate = Value
Exit Function
End If
ValueLen = Len(Value)
If ValueLen = 0 Then
Replicate = vbNullString
Exit Function
ElseIf ValueLen = 1 Then
Replicate = String$(Number, Value)
Exit Function
End If
TempString = String$(Number * ValueLen, Chr(0))
For i = 1 To Number
Mid$(TempString, (i - 1) * ValueLen + 1, ValueLen) = Value
Next
Replicate = TempString
End Function
You can’t perform that action at this time.